Return to submul_1.asm CVS log

Up to [local] / OpenXM_contrib / gmp / mpn / alpha

Annotation of OpenXM_contrib/gmp/mpn/alpha/submul_1.asm, Revision 1.1.1.2

1.1.1.2 ! ohara       1: dnl  Alpha __gmpn_submul_1 -- Multiply a limb vector with a limb and subtract
        !             2: dnl  the result from a second limb vector.
1.1       maekawa     3:
1.1.1.2 ! ohara       4: dnl  Copyright 1992, 1994, 1995, 2000 Free Software Foundation, Inc.
1.1       maekawa     5:
                      6: dnl  This file is part of the GNU MP Library.
                      7:
                      8: dnl  The GNU MP Library is free software; you can redistribute it and/or modify
1.1.1.2 ! ohara       9: dnl  it under the terms of the GNU Lesser General Public License as published
        !            10: dnl  by the Free Software Foundation; either version 2.1 of the License, or (at
        !            11: dnl  your option) any later version.
1.1       maekawa    12:
                     13: dnl  The GNU MP Library is distributed in the hope that it will be useful, but
                     14: dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
                     15: dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
                     16: dnl  License for more details.
                     17:
                     18: dnl  You should have received a copy of the GNU Lesser General Public License
                     19: dnl  along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
                     20: dnl  the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
                     21: dnl  MA 02111-1307, USA.
                     22:
                     23: include(`../config.m4')
                     24:
                     25: dnl  INPUT PARAMETERS
                     26: dnl  res_ptr   r16
                     27: dnl  s1_ptr    r17
                     28: dnl  size      r18
                     29: dnl  s2_limb   r19
                     30:
                     31: dnl  This code runs at 42 cycles/limb on EV4, 18 cycles/limb on EV5, and 7
                     32: dnl  cycles/limb on EV6.
                     33:
                     34: ASM_START()
                     35: PROLOGUE(mpn_submul_1)
                     36:        ldq     r2,0(r17)       C r2 = s1_limb
                     37:        addq    r17,8,r17       C s1_ptr++
                     38:        subq    r18,1,r18       C size--
                     39:        mulq    r2,r19,r3       C r3 = prod_low
                     40:        ldq     r5,0(r16)       C r5 = *res_ptr
                     41:        umulh   r2,r19,r0       C r0 = prod_high
                     42:        beq     r18,$Lend1      C jump if size was == 1
                     43:        ldq     r2,0(r17)       C r2 = s1_limb
                     44:        addq    r17,8,r17       C s1_ptr++
                     45:        subq    r18,1,r18       C size--
                     46:        subq    r5,r3,r3
                     47:        cmpult  r5,r3,r4
                     48:        stq     r3,0(r16)
                     49:        addq    r16,8,r16       C res_ptr++
                     50:        beq     r18,$Lend2      C jump if size was == 2
                     51:
                     52:        ALIGN(8)
                     53: $Loop: mulq    r2,r19,r3       C r3 = prod_low
                     54:        ldq     r5,0(r16)       C r5 = *res_ptr
                     55:        addq    r4,r0,r0        C cy_limb = cy_limb + 'cy'
                     56:        subq    r18,1,r18       C size--
                     57:        umulh   r2,r19,r4       C r4 = cy_limb
                     58:        ldq     r2,0(r17)       C r2 = s1_limb
                     59:        addq    r17,8,r17       C s1_ptr++
                     60:        addq    r3,r0,r3        C r3 = cy_limb + prod_low
                     61:        cmpult  r3,r0,r0        C r0 = carry from (cy_limb + prod_low)
                     62:        subq    r5,r3,r3
                     63:        cmpult  r5,r3,r5
                     64:        stq     r3,0(r16)
                     65:        addq    r16,8,r16       C res_ptr++
                     66:        addq    r5,r0,r0        C combine carries
                     67:        bne     r18,$Loop
                     68:
                     69: $Lend2:        mulq    r2,r19,r3       C r3 = prod_low
                     70:        ldq     r5,0(r16)       C r5 = *res_ptr
                     71:        addq    r4,r0,r0        C cy_limb = cy_limb + 'cy'
                     72:        umulh   r2,r19,r4       C r4 = cy_limb
                     73:        addq    r3,r0,r3        C r3 = cy_limb + prod_low
                     74:        cmpult  r3,r0,r0        C r0 = carry from (cy_limb + prod_low)
                     75:        subq    r5,r3,r3
                     76:        cmpult  r5,r3,r5
                     77:        stq     r3,0(r16)
                     78:        addq    r5,r0,r0        C combine carries
                     79:        addq    r4,r0,r0        C cy_limb = prod_high + cy
                     80:        ret     r31,(r26),1
                     81: $Lend1:        subq    r5,r3,r3
                     82:        cmpult  r5,r3,r5
                     83:        stq     r3,0(r16)
                     84:        addq    r0,r5,r0
                     85:        ret     r31,(r26),1
                     86: EPILOGUE(mpn_submul_1)
                     87: ASM_END()