Return to addmul_1.asm CVS log

Up to [local] / OpenXM_contrib / gmp / mpn / mips32

Annotation of OpenXM_contrib/gmp/mpn/mips32/addmul_1.asm, Revision 1.1

1.1     ! ohara       1: dnl  MIPS32 mpn_addmul_1 -- Multiply a limb vector with a single limb and add
        !             2: dnl  the product to a second limb vector.
        !             3:
        !             4: dnl  Copyright 1992, 1994, 1996, 2000, 2002 Free Software Foundation, Inc.
        !             5:
        !             6: dnl  This file is part of the GNU MP Library.
        !             7:
        !             8: dnl  The GNU MP Library is free software; you can redistribute it and/or modify
        !             9: dnl  it under the terms of the GNU Lesser General Public License as published
        !            10: dnl  by the Free Software Foundation; either version 2.1 of the License, or (at
        !            11: dnl  your option) any later version.
        !            12:
        !            13: dnl  The GNU MP Library is distributed in the hope that it will be useful, but
        !            14: dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
        !            15: dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
        !            16: dnl  License for more details.
        !            17:
        !            18: dnl  You should have received a copy of the GNU Lesser General Public License
        !            19: dnl  along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
        !            20: dnl  the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
        !            21: dnl  MA 02111-1307, USA.
        !            22:
        !            23: include(`../config.m4')
        !            24:
        !            25: C INPUT PARAMETERS
        !            26: C res_ptr      $4
        !            27: C s1_ptr       $5
        !            28: C size         $6
        !            29: C s2_limb      $7
        !            30:
        !            31: ASM_START()
        !            32: PROLOGUE(mpn_addmul_1)
        !            33:
        !            34: C feed-in phase 0
        !            35:        lw      $8,0($5)
        !            36:
        !            37: C feed-in phase 1
        !            38:        addiu   $5,$5,4
        !            39:        multu   $8,$7
        !            40:
        !            41:        addiu   $6,$6,-1
        !            42:        beq     $6,$0,$LC0
        !            43:         move   $2,$0           C zero cy2
        !            44:
        !            45:        addiu   $6,$6,-1
        !            46:        beq     $6,$0,$LC1
        !            47:        lw      $8,0($5)        C load new s1 limb as early as possible
        !            48:
        !            49: Loop:  lw      $10,0($4)
        !            50:        mflo    $3
        !            51:        mfhi    $9
        !            52:        addiu   $5,$5,4
        !            53:        addu    $3,$3,$2        C add old carry limb to low product limb
        !            54:        multu   $8,$7
        !            55:        lw      $8,0($5)        C load new s1 limb as early as possible
        !            56:        addiu   $6,$6,-1        C decrement loop counter
        !            57:        sltu    $2,$3,$2        C carry from previous addition -> $2
        !            58:        addu    $3,$10,$3
        !            59:        sltu    $10,$3,$10
        !            60:        addu    $2,$2,$10
        !            61:        sw      $3,0($4)
        !            62:        addiu   $4,$4,4
        !            63:        bne     $6,$0,Loop
        !            64:         addu   $2,$9,$2        C add high product limb and carry from addition
        !            65:
        !            66: C wind-down phase 1
        !            67: $LC1:  lw      $10,0($4)
        !            68:        mflo    $3
        !            69:        mfhi    $9
        !            70:        addu    $3,$3,$2
        !            71:        sltu    $2,$3,$2
        !            72:        multu   $8,$7
        !            73:        addu    $3,$10,$3
        !            74:        sltu    $10,$3,$10
        !            75:        addu    $2,$2,$10
        !            76:        sw      $3,0($4)
        !            77:        addiu   $4,$4,4
        !            78:        addu    $2,$9,$2        C add high product limb and carry from addition
        !            79:
        !            80: C wind-down phase 0
        !            81: $LC0:  lw      $10,0($4)
        !            82:        mflo    $3
        !            83:        mfhi    $9
        !            84:        addu    $3,$3,$2
        !            85:        sltu    $2,$3,$2
        !            86:        addu    $3,$10,$3
        !            87:        sltu    $10,$3,$10
        !            88:        addu    $2,$2,$10
        !            89:        sw      $3,0($4)
        !            90:        j       $31
        !            91:        addu    $2,$9,$2        C add high product limb and carry from addition
        !            92: EPILOGUE(mpn_addmul_1)