Return to mul_1.asm CVS log

Up to [local] / OpenXM_contrib / gmp / mpn / mips32

Annotation of OpenXM_contrib/gmp/mpn/mips32/mul_1.asm, Revision 1.1

1.1     ! ohara       1: dnl  MIPS32 mpn_mul_1 -- Multiply a limb vector with a single limb and store
        !             2: dnl  the product in a second limb vector.
        !             3:
        !             4: dnl  Copyright 1992, 1994, 1996, 2000, 2002 Free Software Foundation, Inc.
        !             5:
        !             6: dnl  This file is part of the GNU MP Library.
        !             7:
        !             8: dnl  The GNU MP Library is free software; you can redistribute it and/or modify
        !             9: dnl  it under the terms of the GNU Lesser General Public License as published
        !            10: dnl  by the Free Software Foundation; either version 2.1 of the License, or (at
        !            11: dnl  your option) any later version.
        !            12:
        !            13: dnl  The GNU MP Library is distributed in the hope that it will be useful, but
        !            14: dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
        !            15: dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
        !            16: dnl  License for more details.
        !            17:
        !            18: dnl  You should have received a copy of the GNU Lesser General Public License
        !            19: dnl  along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
        !            20: dnl  the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
        !            21: dnl  MA 02111-1307, USA.
        !            22:
        !            23: include(`../config.m4')
        !            24:
        !            25: C INPUT PARAMETERS
        !            26: C res_ptr      $4
        !            27: C s1_ptr       $5
        !            28: C size         $6
        !            29: C s2_limb      $7
        !            30:
        !            31: ASM_START()
        !            32: PROLOGUE(mpn_mul_1)
        !            33:
        !            34: C feed-in phase 0
        !            35:        lw      $8,0($5)
        !            36:
        !            37: C feed-in phase 1
        !            38:        addiu   $5,$5,4
        !            39:        multu   $8,$7
        !            40:
        !            41:        addiu   $6,$6,-1
        !            42:        beq     $6,$0,$LC0
        !            43:         move   $2,$0           C zero cy2
        !            44:
        !            45:        addiu   $6,$6,-1
        !            46:        beq     $6,$0,$LC1
        !            47:        lw      $8,0($5)        C load new s1 limb as early as possible
        !            48:
        !            49: Loop:  mflo    $10
        !            50:        mfhi    $9
        !            51:        addiu   $5,$5,4
        !            52:        addu    $10,$10,$2      C add old carry limb to low product limb
        !            53:        multu   $8,$7
        !            54:        lw      $8,0($5)        C load new s1 limb as early as possible
        !            55:        addiu   $6,$6,-1        C decrement loop counter
        !            56:        sltu    $2,$10,$2       C carry from previous addition -> $2
        !            57:        sw      $10,0($4)
        !            58:        addiu   $4,$4,4
        !            59:        bne     $6,$0,Loop
        !            60:         addu   $2,$9,$2        C add high product limb and carry from addition
        !            61:
        !            62: C wind-down phase 1
        !            63: $LC1:  mflo    $10
        !            64:        mfhi    $9
        !            65:        addu    $10,$10,$2
        !            66:        sltu    $2,$10,$2
        !            67:        multu   $8,$7
        !            68:        sw      $10,0($4)
        !            69:        addiu   $4,$4,4
        !            70:        addu    $2,$9,$2        C add high product limb and carry from addition
        !            71:
        !            72: C wind-down phase 0
        !            73: $LC0:  mflo    $10
        !            74:        mfhi    $9
        !            75:        addu    $10,$10,$2
        !            76:        sltu    $2,$10,$2
        !            77:        sw      $10,0($4)
        !            78:        j       $31
        !            79:        addu    $2,$9,$2        C add high product limb and carry from addition
        !            80: EPILOGUE(mpn_mul_1)