Return to submul_1.s CVS log

Up to [local] / OpenXM_contrib / gmp / mpn / power

Annotation of OpenXM_contrib/gmp/mpn/power/submul_1.s, Revision 1.1.1.2

1.1.1.2 ! maekawa     1: # IBM POWER __gmpn_submul_1 -- Multiply a limb vector with a limb and subtract
1.1       maekawa     2: # the result from a second limb vector.
                      3:
1.1.1.2 ! maekawa     4: # Copyright (C) 1992, 1994, 1999, 2000 Free Software Foundation, Inc.
1.1       maekawa     5:
                      6: # This file is part of the GNU MP Library.
                      7:
                      8: # The GNU MP Library is free software; you can redistribute it and/or modify
1.1.1.2 ! maekawa     9: # it under the terms of the GNU Lesser General Public License as published by
        !            10: # the Free Software Foundation; either version 2.1 of the License, or (at your
1.1       maekawa    11: # option) any later version.
                     12:
                     13: # The GNU MP Library is distributed in the hope that it will be useful, but
                     14: # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
1.1.1.2 ! maekawa    15: # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
1.1       maekawa    16: # License for more details.
                     17:
1.1.1.2 ! maekawa    18: # You should have received a copy of the GNU Lesser General Public License
1.1       maekawa    19: # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
                     20: # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
                     21: # MA 02111-1307, USA.
                     22:
                     23:
                     24: # INPUT PARAMETERS
                     25: # res_ptr      r3
                     26: # s1_ptr       r4
                     27: # size         r5
                     28: # s2_limb      r6
                     29:
1.1.1.2 ! maekawa    30: # The POWER architecture has no unsigned 32x32->64 bit multiplication
        !            31: # instruction.  To obtain that operation, we have to use the 32x32->64 signed
        !            32: # multiplication instruction, and add the appropriate compensation to the high
        !            33: # limb of the result.  We add the multiplicand if the multiplier has its most
        !            34: # significant bit set, and we add the multiplier if the multiplicand has its
        !            35: # most significant bit set.  We need to preserve the carry flag between each
1.1       maekawa    36: # iteration, so we have to compute the compensation carefully (the natural,
1.1.1.2 ! maekawa    37: # srai+and doesn't work).  Since the POWER architecture has a branch unit we
        !            38: # can branch in zero cycles, so that's how we perform the additions.
1.1       maekawa    39:
                     40:        .toc
1.1.1.2 ! maekawa    41:        .globl  __gmpn_submul_1
        !            42:        .globl  .__gmpn_submul_1
        !            43:        .csect  __gmpn_submul_1[DS]
        !            44: __gmpn_submul_1:
        !            45:        .long   .__gmpn_submul_1, TOC[tc0], 0
        !            46:        .csect  .text[PR]
        !            47:        .align  2
        !            48: .__gmpn_submul_1:
1.1       maekawa    49:
                     50:        cal     3,-4(3)
                     51:        l       0,0(4)
                     52:        cmpi    0,6,0
                     53:        mtctr   5
                     54:        mul     9,0,6
                     55:        srai    7,0,31
                     56:        and     7,7,6
                     57:        mfmq    11
                     58:        cax     9,9,7
                     59:        l       7,4(3)
                     60:        sf      8,11,7          # add res_limb
                     61:        a       11,8,11         # invert cy (r11 is junk)
                     62:        blt     Lneg
                     63: Lpos:  bdz     Lend
                     64:
                     65: Lploop:        lu      0,4(4)
                     66:        stu     8,4(3)
                     67:        cmpi    0,0,0
                     68:        mul     10,0,6
                     69:        mfmq    0
                     70:        ae      11,0,9          # low limb + old_cy_limb + old cy
                     71:        l       7,4(3)
                     72:        aze     10,10           # propagate cy to new cy_limb
                     73:        sf      8,11,7          # add res_limb
                     74:        a       11,8,11         # invert cy (r11 is junk)
                     75:        bge     Lp0
                     76:        cax     10,10,6         # adjust high limb for negative limb from s1
                     77: Lp0:   bdz     Lend0
                     78:        lu      0,4(4)
                     79:        stu     8,4(3)
                     80:        cmpi    0,0,0
                     81:        mul     9,0,6
                     82:        mfmq    0
                     83:        ae      11,0,10
                     84:        l       7,4(3)
                     85:        aze     9,9
                     86:        sf      8,11,7
                     87:        a       11,8,11         # invert cy (r11 is junk)
                     88:        bge     Lp1
                     89:        cax     9,9,6           # adjust high limb for negative limb from s1
                     90: Lp1:   bdn     Lploop
                     91:
                     92:        b       Lend
                     93:
                     94: Lneg:  cax     9,9,0
                     95:        bdz     Lend
                     96: Lnloop:        lu      0,4(4)
                     97:        stu     8,4(3)
                     98:        cmpi    0,0,0
                     99:        mul     10,0,6
                    100:        mfmq    7
                    101:        ae      11,7,9
                    102:        l       7,4(3)
                    103:        ae      10,10,0         # propagate cy to new cy_limb
                    104:        sf      8,11,7          # add res_limb
                    105:        a       11,8,11         # invert cy (r11 is junk)
                    106:        bge     Ln0
                    107:        cax     10,10,6         # adjust high limb for negative limb from s1
                    108: Ln0:   bdz     Lend0
                    109:        lu      0,4(4)
                    110:        stu     8,4(3)
                    111:        cmpi    0,0,0
                    112:        mul     9,0,6
                    113:        mfmq    7
                    114:        ae      11,7,10
                    115:        l       7,4(3)
                    116:        ae      9,9,0           # propagate cy to new cy_limb
                    117:        sf      8,11,7          # add res_limb
                    118:        a       11,8,11         # invert cy (r11 is junk)
                    119:        bge     Ln1
                    120:        cax     9,9,6           # adjust high limb for negative limb from s1
                    121: Ln1:   bdn     Lnloop
                    122:        b       Lend
                    123:
                    124: Lend0: cal     9,0(10)
                    125: Lend:  st      8,4(3)
                    126:        aze     3,9
                    127:        br